HPAVC/HPAVC CD-ROM.iso/LORD2B6.ZIP/GENRAN.REF

Text File | 1997-05-16 | 3KB | 179 lines

;general random stuff that is usually called from any major tavel route
;where roads are


@#GENRAN
@do `p20 random 2 1


@if `p20 is 1 then do
 @begin
 @run event1
 @end

@if `p20 is 2 then do
  @begin
  @run event2
  @end

@#event2
@do moveback
@do write
`r1
@clearblock 21 21
@do move 3 21
@do write
`r0  `2A dark robed priest approaches.  Speak with him? [`0Y`2/`0N`2] :`x
@do readspecial `s01 YN

@if `s01 is Y then do
  @begin
  @label ev1
  @show
`r0`c  `r1  A deal, perhaps?  `r0

  `0"Greetings fellow traveler.  Would you be interested in a traveling
  potion for `$$500`0?" `2the priest asks.

@do write
`x`x
@choice
Exactly how does it work, strange dark robed priest?
>&money 499 Yes, I'll take it!
>&money 499 No thanks.
<&money 500 I can't afford it.
@if response is 1 then do
  @begin
  @show
`r0`c  `r1  How it works  `r0

  `0"It's really very simple young s&man, first you drink it.  Then you
  wait.  You will be randomly teleported to one of ten various places."

  `$"What if I don't like where I am?"

`k  `0"Then you're pretty much screwed, aren't you," `2he laughs.

  `$"Hey!  A priest isn't supposed to talk like that!" `2you accuse.

`k  `0"We're also not supposed to sell illegal drugs, what's your point?"

`k
  @do goto ev1
  @end
 @if response is 2 then do
   @begin
   @show
`\`\  `0"Great doing business with you," `2he smiles as he hands you a
  funny looking vial.
`\`k
   @drawmap
   @update
   @do `i50 + 1
   @do money - 500
   @closescript
   @end



 @if response is 3 then do
   @begin
   @show
`\`\  `0"Maybe next time, friend," `2he smiles.
`\`k
   @drawmap
   @update
   @closescript
   @end


 @if response is 4 then do
   @begin
   @show
`\`\  `0"Maybe next time, friend," `2he smiles.
`\`k
   @drawmap
   @update
   @closescript
   @end


  @end
@do saybar
You move to the side to let him pass.

@#event1
@do moveback
@do write
`r1
@clearblock 21 21
@do move 3 21
@do write
`r0  `2A hooded figure approaches.  Speak with him? [`0Y`2/`0N`2] :`x
@do readspecial `s01 YN

@if `s01 is Y then do
  @begin
  @busy
  @do `p20 random 4 1
  @if `p20 is 1 then `s10 is `+22
  @if `p20 is 2 then `s10 is `+23
  @if `p20 is 3 then `s10 is `+24
  @if `p20 is 4 then `s10 is `+25

  @show
`r0`c  `r1  Dark Trading `r0

  `0"Greetings, stranger.  I have a very magical item called a `%`s10
  `0for sale.. would you like to buy it for `$$100`0?"
  @do write
`\`x`x
  @do `v01 is 1
  @choice
>&money 99 Sure, I'll take it
>&money 99 I don't deal with your type.
<&money 100 Sorry, I can't afford that.
  @if response is 1 then do
    @begin
  @if `p20 is 1 then `i22 + 1
  @if `p20 is 2 then `i23 + 1
  @if `p20 is 3 then `i24 + 1
  @if `p20 is 4 then `i25 + 1
    @do money - 100
  @show
`\`\  `0"Nice doing business with you," `2the dark trader laughs evilly as
  he hands you the `%`s10`2.
`\`k
    @drawmap
    @update
    @closescript
    @end

  @if response is 2 then do
   @begin
   @show
`\`\  `0"You are making a mistake.." `2the dark trader grunts as he leaves.
`\`k
   @drawmap
   @update
   @closescript
   @end

   @show
`\`\  `0"Maybe next time.." `2the dark trader grunts as he leaves.
`\`k
   @drawmap
   @update
  @closescript

 @end

@do saybar
You move to the side to let him pass.





@#done